configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [3])
   6 m4_define([empathy_micro_version], [2])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.6.2
  38 GLIB_REQUIRED=2.30.0
  39 GNUTLS_REQUIRED=2.8.5
  40 GTK_REQUIRED=3.0.2
  41 GSTREAMER_REQUIRED=0.10.32
  42 KEYRING_REQUIRED=2.26.0
  43 GCR_REQUIRED=2.91.4
  44 LIBCANBERRA_GTK_REQUIRED=0.25
  45 LIBNOTIFY_REQUIRED=0.7.0
  46 TELEPATHY_FARSIGHT_REQUIRED=0.0.18
  47 TELEPATHY_GLIB_REQUIRED=0.17.0
  48 TELEPATHY_LOGGER=0.2.10
  49 WEBKIT_REQUIRED=1.3.13
  50 GOA_REQUIRED=3.3.0
  51
  52 # Optional deps
  53 CLUTTER_REQUIRED=1.7.14
  54 CLUTTER_GTK_REQUIRED=0.90.3
  55 ENCHANT_REQUIRED=1.2.0
  56 GEOCLUE_REQUIRED=0.11
  57 ISO_CODES_REQUIRED=0.35
  58 NAUTILUS_SENDTO_REQUIRED=2.90.0
  59 NETWORK_MANAGER_REQUIRED=0.7.0
  60
  61 # Use --enable-maintainer-mode to disable deprecated symbols,
  62 # disable single include and enable GSEAL. If this is not a released empathy,
  63 # maintainer mode is forced
  64 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  65 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  66 #GNOME_MAINTAINER_MODE_DEFINES
  67
  68 # Disable GLib deprecation warnings for now; we don't want to bump the GLib dep
  69 # and make things harder for contributiors without good reason. We'll re-enable
  70 # those warnings later during the cycle (bgo #662662)
  71 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
  72
  73 # telepathy-yell
  74 prev_top_build_prefix=$ac_top_build_prefix
  75 prev_ac_configure_args=$ac_configure_args
  76 ac_configure_args="$ac_configure_args --disable-shared-library"
  77 AX_CONFIG_DIR([telepathy-yell])
  78 ac_top_build_prefix=$prev_top_build_prefix
  79 ac_configure_args=$prev_ac_configure_args
  80 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-yell/telepathy-yell
  81
  82 AC_CONFIG_MACRO_DIR([m4])
  83 AC_CONFIG_HEADERS([config.h])
  84 AC_CONFIG_SRCDIR([configure.ac])
  85 AC_CONFIG_AUX_DIR(.)
  86
  87 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
  88
  89 # Support silent build rules. Disable
  90 # by either passing --disable-silent-rules to configure or passing V=1
  91 # to make
  92 AM_SILENT_RULES([yes])
  93
  94 # Check for programs
  95 AC_PROG_CC
  96 AC_HEADER_STDC
  97 AM_PROG_MKDIR_P
  98 AM_PATH_GLIB_2_0
  99 AC_PATH_XTRA
 100
 101 # Initialize libtool
 102 LT_PREREQ([2.2])
 103 LT_INIT
 104
 105 GNOME_DOC_INIT([0.17.3])
 106 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 107 GLIB_GSETTINGS
 108 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 109 AC_SUBST(GLIB_GENMARSHAL)
 110
 111 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 112 if test -z "$XSLTPROC"; then
 113   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 114 fi
 115 AM_PATH_PYTHON([2.3])
 116
 117 EMPATHY_ARG_VALGRIND
 118
 119
 120 # -----------------------------------------------------------
 121 # Error flags
 122 # -----------------------------------------------------------
 123 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 124 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 125
 126 AC_ARG_ENABLE(Werror,
 127   AS_HELP_STRING([--disable-Werror],
 128                  [compile without -Werror (normally enabled in development builds)]),
 129     werror=$enableval, :)
 130
 131 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 132 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 133         wno_missing_field_initializers=yes,
 134         wno_missing_field_initializers=no)
 135 AS_COMPILER_FLAG(-Wno-unused-parameter,
 136         wno_unused_parameter=yes,
 137         wno_unused_parameter=no)
 138
 139 ifelse(empathy_released, 1, [],
 140     [
 141         if test x$werror = xyes; then
 142             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 143         fi
 144         if test x$wextra = xyes -a \
 145             x$wno_missing_field_initializers = xyes -a \
 146             x$wno_unused_parameter = xyes; then
 147             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 148         fi
 149     ])
 150
 151 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 152 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 153 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 154 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 155 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 156
 157 AC_SUBST(ERROR_CFLAGS)
 158
 159 AC_ARG_ENABLE(gprof,
 160             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 161             [build with support for gprof]),,
 162             [enable_gprof=no])
 163 if test "x$enable_gprof" != "xno" ; then
 164     CFLAGS="$CFLAGS -pg"
 165     LDFLAGS="$LDFLAGS -pg"
 166 fi
 167
 168 AC_SUBST(LDFLAGS)
 169
 170 # -----------------------------------------------------------
 171 # Pkg-Config dependency checks
 172 # -----------------------------------------------------------
 173
 174 AC_CHECK_LIBM
 175 AC_SUBST(LIBM)
 176
 177 PKG_CHECK_MODULES(EMPATHY,
 178 [
 179    dbus-glib-1
 180    folks >= $FOLKS_REQUIRED
 181    folks-telepathy >= $FOLKS_REQUIRED
 182    glib-2.0 >= $GLIB_REQUIRED
 183    gio-2.0 >= $GLIB_REQUIRED
 184    gio-unix-2.0 >= $GLIB_REQUIRED
 185    gnome-keyring-1 >= $KEYRING_REQUIRED
 186    gnutls >= $GNUTLS_REQUIRED
 187    gmodule-export-2.0
 188    gobject-2.0
 189    gsettings-desktop-schemas
 190    gstreamer-0.10 >= $GSTREAMER_REQUIRED
 191    gstreamer-interfaces-0.10
 192    libxml-2.0
 193    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 194    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 195    x11
 196    gtk+-3.0 >= $GTK_REQUIRED
 197    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 198    libnotify >= $LIBNOTIFY_REQUIRED
 199    gcr-3 >= $GCR_REQUIRED
 200    libpulse
 201    libpulse-mainloop-glib
 202    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 203    libsoup-2.4
 204 ])
 205
 206 PKG_CHECK_MODULES(YELL, [telepathy-yell])
 207
 208 PKG_CHECK_MODULES(EMPATHY_AV,
 209 [
 210    farsight2-0.10
 211    telepathy-farsight >= $TELEPATHY_FARSIGHT_REQUIRED
 212 ])
 213
 214 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 215    [Name of provider for accounts imported from GOA])
 216
 217 # -----------------------------------------------------------
 218 # Call interface
 219 # -----------------------------------------------------------
 220 AC_ARG_ENABLE(call,
 221             AS_HELP_STRING([--enable-call=@<:@no/yes/auto@:>@],
 222             [build with Call interface support]),,
 223             [enable_call=auto])
 224 if test "x$enable_call" != "xno" ; then
 225    PKG_CHECK_MODULES(EMPATHY_CALL,
 226    [
 227       farsight2-0.10
 228       telepathy-farstream >= 0.1.2
 229       clutter-1.0 >= $CLUTTER_REQUIRED
 230       clutter-gtk-1.0
 231       clutter-gst-1.0
 232    ], have_call="yes", have_call="no" )
 233
 234    if test "x$have_call" = "xyes"; then
 235       AC_DEFINE(HAVE_CALL, 1, [Define if you have Call channel support])
 236    fi
 237 else
 238   have_call=no
 239 fi
 240
 241 if test "x$enable_call" = "xyes" -a "x$have_call" != "xyes"; then
 242    AC_MSG_ERROR([Could not find Call handler dependencies:
 243
 244 $EMPATHY_CALL_PKG_ERRORS])
 245 fi
 246 AM_CONDITIONAL(HAVE_CALL, test "x$have_call" = "xyes")
 247
 248
 249 # -----------------------------------------------------------
 250 # Call support in tp-logger
 251 # -----------------------------------------------------------
 252 AC_ARG_ENABLE(call-logs,
 253             AS_HELP_STRING([--enable-call-logs=@<:@no/yes/auto@:>@],
 254             [build with call logs support]),,
 255             [enable_call_logs=auto])
 256 if test "x$enable_call_logs" != "xno" ; then
 257    SAVE_CFLAGS=$CFLAGS
 258    SAVE_CPPFLAGS=$CPPFLAGS
 259    SAVE_LDFLAGS=$LDFLAGS
 260    CFLAGS="$CFLAGS $EMPATHY_CFLAGS"
 261    CPPFLAGS="$CPPFLAGS $EMPATHY_CFLAGS"
 262    LDFLAGS="$LDFLAGS $EMPATHY_LDFLAGS"
 263
 264    AC_CHECK_HEADER(telepathy-logger/call-event.h,
 265       have_call_logs="yes", have_call_logs="no")
 266
 267    CFLAGS=$SAVE_CFLAGS
 268    CPPFLAGS=$SAVE_CPPFLAGS
 269    LDFLAGS=$SAVE_LDFLAGS
 270
 271    if test "x$have_call_logs" = "xyes"; then
 272       AC_DEFINE(HAVE_CALL_LOGS, 1, [Define if you have call log support])
 273    fi
 274 else
 275   have_call_logs=no
 276 fi
 277
 278 if test "x$enable_call_logs" = "xyes" -a "x$have_call_logs" != "xyes"; then
 279    AC_MSG_ERROR([Call logs support requested but telepathy-logger wasn't
 280                  built with --enable-call])
 281 fi
 282
 283 # -----------------------------------------------------------
 284 # evolution-data-server (about-me)
 285 # -----------------------------------------------------------
 286 AC_ARG_WITH(eds,
 287             AS_HELP_STRING([--with-eds],
 288                            [build with evolution-data-server support]),,
 289             [with_eds=yes])
 290 if test x"$with_eds" = x"yes" ; then
 291    PKG_CHECK_MODULES(EDS, [libebook-1.2])
 292    AC_DEFINE(HAVE_EDS, 1, [Define if we have libebook])
 293 fi
 294
 295 # -----------------------------------------------------------
 296 # Enable debug
 297 # -----------------------------------------------------------
 298
 299 AC_ARG_ENABLE(debug,
 300   AS_HELP_STRING([--disable-debug],
 301                  [compile without debug code]),
 302     enable_debug=$enableval, enable_debug=yes )
 303
 304 if test x$enable_debug = xyes; then
 305   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 306 fi
 307
 308 # -----------------------------------------------------------
 309 # Language Support
 310 # -----------------------------------------------------------
 311 IT_PROG_INTLTOOL([0.40.0])
 312
 313 AM_GNU_GETTEXT_VERSION([0.17])
 314 AM_GNU_GETTEXT([external])
 315
 316 GETTEXT_PACKAGE=empathy
 317 AC_SUBST(GETTEXT_PACKAGE)
 318 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 319
 320 # -----------------------------------------------------------
 321 # Connectivity integration
 322 # -----------------------------------------------------------
 323 AC_ARG_WITH(connectivity,
 324               AS_HELP_STRING([--with-connectivity=@<:@nm/connman/auto/no@:>@],
 325                              [build with connectivity support]), ,
 326                              with_connectivity=auto)
 327
 328 if test "x$with_connectivity" = "xno"; then
 329    have_nm=no
 330    have_connman=no
 331
 332 elif test "x$with_connectivity" = "xconnman"; then
 333    have_nm=no
 334
 335    PKG_CHECK_MODULES(CONNMAN,
 336    [
 337       dbus-glib-1
 338    ], have_connman="yes", have_connman="no")
 339
 340    if test "x$have_connman" = "xyes"; then
 341       AC_DEFINE(HAVE_CONNMAN, 1, [Define if you have connman dependencies])
 342    fi
 343
 344 else
 345    have_connman=no
 346
 347    PKG_CHECK_MODULES(NETWORK_MANAGER,
 348    [
 349       libnm-glib >= $NETWORK_MANAGER_REQUIRED
 350    ], have_nm="yes", have_nm="no")
 351
 352    if test "x$have_nm" = "xyes"; then
 353       AC_DEFINE(HAVE_NM, 1, [Define if you have libnm-glib])
 354    fi
 355 fi
 356
 357 if test "x$with_connectivity" = "xconnman" -a "x$have_connman" != "xyes"; then
 358    AC_MSG_ERROR([Couldn't find connman dependencies:
 359
 360 $CONNMAN_PKG_ERRORS])
 361 fi
 362
 363 if test "x$with_connectivity" = "xnm" -a "x$have_nm" != "xyes"; then
 364    AC_MSG_ERROR([Couldn't find Network Manager dependencies:
 365
 366 $NETWORK_MANAGER_PKG_ERRORS])
 367 fi
 368
 369 AM_CONDITIONAL(HAVE_NM, test "x$have_nm" = "xyes")
 370 AM_CONDITIONAL(HAVE_CONNMAN, test "x$have_connman" = "xyes")
 371
 372 # -----------------------------------------------------------
 373 # gudev
 374 # -----------------------------------------------------------
 375 AC_ARG_ENABLE(gudev,
 376               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 377                              [build with gudev support]), ,
 378                              enable_gudev=auto)
 379
 380 if test "x$enable_gudev" != "xno"; then
 381
 382    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 383         have_gudev="yes", have_gudev="no")
 384
 385    if test "x$have_gudev" = "xyes"; then
 386       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 387    fi
 388 else
 389    have_gudev=no
 390 fi
 391
 392 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 393    AC_MSG_ERROR([Could not find gudev dependencies:
 394
 395 $UDEV_PKG_ERRORS])
 396 fi
 397 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 398
 399 # -----------------------------------------------------------
 400 # spellchecking checks: enchant and iso-codes
 401 # -----------------------------------------------------------
 402 AC_ARG_ENABLE(spell,
 403               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 404                              [Enable spell checking]), ,
 405                              enable_spell=auto)
 406
 407 if test "x$enable_spell" != "xno"; then
 408    PKG_CHECK_MODULES(ENCHANT,
 409    [
 410       enchant >= $ENCHANT_REQUIRED,
 411       iso-codes >= $ISO_CODES_REQUIRED
 412    ], have_enchant="yes", have_enchant="no")
 413
 414    if test "x$have_enchant" = "xyes"; then
 415       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 416       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 417          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 418             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 419             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 420             result=yes
 421       else
 422             result=no
 423             have_enchant="no"
 424       fi
 425       AC_MSG_RESULT([$result])
 426    fi
 427 else
 428    have_enchant=no
 429 fi
 430
 431 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 432    AC_MSG_ERROR([Could not find spell-checking dependencies:
 433
 434 $ENCHANT_PKG_ERRORS])
 435 fi
 436
 437 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 438
 439 # -----------------------------------------------------------
 440 # Map view checks: libchamplain
 441 # -----------------------------------------------------------
 442 AC_ARG_ENABLE(map,
 443               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 444                              [Enable map view]), ,
 445                              enable_map=auto)
 446
 447 if test "x$enable_map" != "xno"; then
 448
 449    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 450     [
 451        clutter-gtk-1.0
 452        champlain-gtk-0.12
 453        champlain-0.12
 454     ], have_libchamplain="yes", have_libchamplain="no")
 455
 456    if test "x$have_libchamplain" = "xyes"; then
 457       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 458    fi
 459 else
 460    have_libchamplain=no
 461 fi
 462
 463 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 464    AC_MSG_ERROR([Could not find map view dependencies:
 465
 466 $LIBCHAMPLAIN_PKG_ERRORS])
 467 fi
 468
 469 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 470
 471 # -----------------------------------------------------------
 472 # location checks: geoclue
 473 # -----------------------------------------------------------
 474 AC_ARG_ENABLE(location,
 475               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 476                              [Enable location awareness]), ,
 477                              enable_location=auto)
 478
 479 if test "x$enable_location" != "xno"; then
 480    PKG_CHECK_MODULES(GEOCLUE,
 481    [
 482       geoclue >= $GEOCLUE_REQUIRED
 483    ], have_geoclue="yes", have_geoclue="no")
 484
 485    if test "x$have_geoclue" = "xyes"; then
 486       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 487    fi
 488 else
 489    have_geoclue="no"
 490 fi
 491
 492 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 493    AC_MSG_ERROR([Could not find location dependencies:
 494
 495 $GEOCLUE_PKG_ERRORS])
 496 fi
 497
 498 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 499 AC_SUBST(GEOCLUE_CFLAGS)
 500 AC_SUBST(GEOCLUE_LIBS)
 501
 502 # -----------------------------------------------------------
 503 # location checks: geocode-glib
 504 # -----------------------------------------------------------
 505 AC_ARG_ENABLE(geocode,
 506               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 507                              [Enable geocode support]), ,
 508                              enable_geocode=auto)
 509
 510 if test "x$enable_geocode" != "xno"; then
 511    PKG_CHECK_MODULES(GEOCODE,
 512    [
 513       geocode-glib
 514    ], have_geocode="yes", have_geocode="no")
 515
 516    if test "x$have_geocode" = "xyes"; then
 517       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 518    fi
 519 else
 520    have_geocode="no"
 521 fi
 522
 523 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 524    AC_MSG_ERROR([Could not find geocode dependencies:
 525
 526 $GEOCODE_PKG_ERRORS])
 527 fi
 528
 529 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 530 AC_SUBST(GEOCODE_CFLAGS)
 531 AC_SUBST(GEOCODE_LIBS)
 532
 533 # -----------------------------------------------------------
 534 # meego widgets support
 535 # -----------------------------------------------------------
 536 AC_ARG_ENABLE(meego,
 537               AS_HELP_STRING([--enable-meego=@<:@no/yes@:>@],
 538                              [Enable meego widgets]), ,
 539                              enable_meego=no)
 540
 541 if test "x$enable_meego" != "xno"; then
 542     PKG_CHECK_MODULES(MEEGO,
 543     [
 544        mx-gtk-1.0
 545        gio-unix-2.0
 546     ], have_meego="yes", have_meego="no")
 547
 548     if test "x$have_meego" = "xyes"; then
 549        AC_DEFINE(HAVE_MEEGO, 1, [Define if you have meego])
 550     fi
 551 else
 552    have_meego="no"
 553 fi
 554
 555 if test "x$enable_meego" = "xyes" -a "x$have_meego" != "xyes"; then
 556    AC_MSG_ERROR([Could not find meego dependencies:
 557
 558 $MEEGO_PKG_ERRORS])
 559 fi
 560
 561 AM_CONDITIONAL(HAVE_MEEGO, test "x$have_meego" = "xyes")
 562 AC_SUBST(MEEGO_CFLAGS)
 563 AC_SUBST(MEEGO_LIBS)
 564
 565 # -----------------------------------------------------------
 566 # nautilus-sendto
 567 # -----------------------------------------------------------
 568 AC_ARG_ENABLE(nautilus-sendto,
 569               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 570                              [build nautilus-sendto plugin]), ,
 571                              enable_nautilus_sendto=auto)
 572
 573 if test "x$enable_nautilus_sendto" != "xno"; then
 574    PKG_CHECK_MODULES(NST,
 575     [
 576        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 577     ], have_nst="yes", have_nst="no")
 578 else
 579    have_nst=no
 580 fi
 581
 582 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 583    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 584
 585 $NST_PKG_ERRORS])
 586 fi
 587
 588 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 589
 590 # -----------------------------------------------------------
 591 # goa-mc-plugin
 592 # -----------------------------------------------------------
 593 AC_ARG_ENABLE(goa,
 594               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 595                              [build GOA MC plugin]), ,
 596                              enable_goa=auto)
 597
 598 if test "x$enable_goa" != "xno"; then
 599    PKG_CHECK_MODULES(GOA,
 600     [
 601        mission-control-plugins
 602        goa-1.0 >= $GOA_REQUIRED
 603     ], have_goa="yes", have_goa="no")
 604
 605    AC_MSG_CHECKING([Mission Control plugins dir])
 606    MISSION_CONTROL_PLUGINS_DIR=`pkg-config --variable=plugindir mission-control-plugins`
 607
 608    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 609    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 610 else
 611    have_goa=no
 612 fi
 613
 614 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 615    AC_MSG_ERROR([Could not find GOA dependencies.])
 616 fi
 617
 618 if test "x$have_goa" = "xyes"; then
 619    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 620 fi
 621
 622 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 623
 624 # Optional dependency for avatar selection
 625 AC_ARG_WITH([cheese],
 626             AS_HELP_STRING([--with-cheese],
 627                            [enable cheese webcam support]),,
 628             with_cheese=auto)
 629
 630 if test x"$with_cheese" != x"no" ; then
 631    PKG_CHECK_MODULES(CHEESE, gstreamer-0.10 cheese-gtk >= 2.91.91.1, [have_cheese=yes], [have_cheese=no])
 632    if test x${have_cheese} = xyes; then
 633      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 634    fi
 635    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 636      AC_MSG_ERROR([Cheese configured but not found:
 637
 638 $CHEESE_PKG_ERRORS])
 639    fi
 640 else
 641    have_cheese=no
 642 fi
 643 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 644
 645
 646 # -----------------------------------------------------------
 647 # Coding style checks
 648 # -----------------------------------------------------------
 649 AC_ARG_ENABLE(coding-style-checks,
 650   AS_HELP_STRING([--disable-coding-style-checks],
 651                  [do not check coding style using grep]),
 652     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 653     [ENABLE_CODING_STYLE_CHECKS=yes])
 654
 655 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 656 # -----------------------------------------------------------
 657
 658 AC_CONFIG_FILES([
 659    Makefile
 660    data/Makefile
 661    data/empathy.desktop.in
 662    data/empathy-accounts.desktop.in
 663    data/icons/Makefile
 664    extensions/Makefile
 665    po/Makefile.in
 666    libempathy/Makefile
 667    libempathy-gtk/Makefile
 668    src/Makefile
 669    nautilus-sendto-plugin/Makefile
 670    goa-mc-plugin/Makefile
 671    help/Makefile
 672    tests/Makefile
 673    tests/interactive/Makefile
 674    tests/xml/Makefile
 675    tools/Makefile
 676 ])
 677 AC_OUTPUT
 678
 679 echo "
 680 Configure summary:
 681
 682         Compiler....................:  ${CC}
 683         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 684         Linker Flags................:  ${LDFLAGS}
 685         Prefix......................:  ${prefix}
 686         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 687
 688     Features:
 689         Spell checking (enchant)....:  ${have_enchant}
 690         Display maps (libchamplain).:  ${have_libchamplain}
 691         Location awareness (Geoclue):  ${have_geoclue}
 692         Geocode support (Geocode)...:  ${have_geocode}
 693         Meego widgets...............:  ${have_meego}
 694         Cheese webcam support ......:  ${have_cheese}
 695         Camera monitoring...........:  ${have_gudev}
 696
 697     Connectivity:
 698         NetworkManager integration..:  ${have_nm}
 699         ConnMan integration.........:  ${have_connman}
 700
 701     Extras:
 702         Nautilus-sendto plugin......:  ${have_nst}
 703         GOA MC plugin...............:  ${have_goa}
 704         Salut E-D-S support.........:  ${with_eds}
 705         Exp. Call channel handler...:  ${have_call}
 706         Exp. Call log support.......:  ${have_call_logs}
 707 "