configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 1)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [7])
   6 m4_define([empathy_micro_version], [91])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.7.3
  38 GNUTLS_REQUIRED=2.8.5
  39
  40 GLIB_REQUIRED=2.33.3
  41 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30, [Ignore post 2.30 deprecations])
  42 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_34, [Prevent post 2.34 APIs])
  43
  44 GTK_REQUIRED=3.5.1
  45 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_4, [Ignore post 3.4 deprecations])
  46 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_4, [Prevent post 3.4 APIs])
  47
  48 CLUTTER_REQUIRED=1.10.0
  49 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  50 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  51
  52 CLUTTER_GTK_REQUIRED=1.1.2
  53
  54 TELEPATHY_GLIB_REQUIRED=0.19.9
  55 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  56 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_20, [Prevent post 0.20 APIs])
  57 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  58 AC_DEFINE(TP_DISABLE_SINGLE_INCLUDE, 1, [Disable single include header])
  59
  60 GSTREAMER_REQUIRED=0.10.32
  61 TP_FS_REQUIRED=0.6.0
  62 LIBSECRET_REQUIRED=0.5
  63 GCR_REQUIRED=2.91.4
  64 LIBCANBERRA_GTK_REQUIRED=0.25
  65 LIBNOTIFY_REQUIRED=0.7.0
  66 TELEPATHY_LOGGER=0.8.0
  67 WEBKIT_REQUIRED=1.9.1
  68 GOA_REQUIRED=3.5.1
  69
  70 # Optional deps
  71 ENCHANT_REQUIRED=1.2.0
  72 GEOCLUE_REQUIRED=0.12
  73 GEOCODE_GLIB_REQUIRED=0.99.1
  74 ISO_CODES_REQUIRED=0.35
  75 NAUTILUS_SENDTO_REQUIRED=2.90.0
  76 NETWORK_MANAGER_REQUIRED=0.7.0
  77 CHAMPLAIN_REQUIRED=0.12.1
  78 CHEESE_GTK_REQUIRED=3.4.0
  79 LIBACCOUNTS_REQUIRED=1.4
  80 LIBSIGNON_REQUIRED=1.1
  81 MC_PLUGINS_REQUIRED=5.13.1
  82
  83 # Use --enable-maintainer-mode to disable deprecated symbols,
  84 # disable single include and enable GSEAL. If this is not a released empathy,
  85 # maintainer mode is forced
  86 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  87 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  88 #GNOME_MAINTAINER_MODE_DEFINES
  89
  90 # egg-list-box
  91 prev_top_build_prefix=$ac_top_build_prefix
  92 prev_ac_configure_args=$ac_configure_args
  93 AX_CONFIG_DIR([libempathy-gtk/egg-list-box])
  94 ac_top_build_prefix=$prev_top_build_prefix
  95 ac_configure_args=$prev_ac_configure_args
  96
  97 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"libempathy-gtk/egg-list-box
  98 PKG_CHECK_MODULES(EGGLISTBOX, egg-list-box)
  99
 100 AC_CONFIG_MACRO_DIR([m4])
 101 AC_CONFIG_HEADERS([config.h])
 102 AC_CONFIG_SRCDIR([configure.ac])
 103 AC_CONFIG_AUX_DIR(.)
 104
 105 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 106
 107 # Support silent build rules. Disable
 108 # by either passing --disable-silent-rules to configure or passing V=1
 109 # to make
 110 AM_SILENT_RULES([yes])
 111
 112 # Check for programs
 113 AC_PROG_CC
 114 AC_HEADER_STDC
 115 AM_PROG_MKDIR_P
 116 AM_PATH_GLIB_2_0
 117 AC_PATH_XTRA
 118
 119 # Initialize libtool
 120 LT_PREREQ([2.2])
 121 LT_INIT
 122
 123 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 124 GLIB_GSETTINGS
 125
 126 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG gio-2.0 --variable=glib_compile_resources`
 127 AC_SUBST(GLIB_COMPILE_RESOURCES)
 128 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 129 AC_SUBST(GLIB_GENMARSHAL)
 130
 131 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 132 if test -z "$XSLTPROC"; then
 133   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 134 fi
 135 AM_PATH_PYTHON([2.3])
 136
 137 EMPATHY_ARG_VALGRIND
 138
 139
 140 # -----------------------------------------------------------
 141 # Error flags
 142 # -----------------------------------------------------------
 143 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 144 AS_COMPILER_FLAG(-Werror, werror=yes, werror=no)
 145
 146 AC_ARG_ENABLE(Werror,
 147   AS_HELP_STRING([--disable-Werror],
 148                  [compile without -Werror (normally enabled in development builds)]),
 149     werror=$enableval, :)
 150
 151 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 152 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 153         wno_missing_field_initializers=yes,
 154         wno_missing_field_initializers=no)
 155 AS_COMPILER_FLAG(-Wno-unused-parameter,
 156         wno_unused_parameter=yes,
 157         wno_unused_parameter=no)
 158
 159 ifelse(empathy_released, 1, [],
 160     [
 161         if test x$werror = xyes; then
 162             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 163         fi
 164         if test x$wextra = xyes -a \
 165             x$wno_missing_field_initializers = xyes -a \
 166             x$wno_unused_parameter = xyes; then
 167             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 168         fi
 169     ])
 170
 171 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 172 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 173 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 174 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 175 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 176
 177 AC_SUBST(ERROR_CFLAGS)
 178
 179 AC_ARG_ENABLE(gprof,
 180             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 181             [build with support for gprof]),,
 182             [enable_gprof=no])
 183 if test "x$enable_gprof" != "xno" ; then
 184     CFLAGS="$CFLAGS -pg"
 185     LDFLAGS="$LDFLAGS -pg"
 186 fi
 187
 188 AC_SUBST(LDFLAGS)
 189
 190 # -----------------------------------------------------------
 191 # Pkg-Config dependency checks
 192 # -----------------------------------------------------------
 193
 194 AC_CHECK_LIBM
 195 AC_SUBST(LIBM)
 196
 197 PKG_CHECK_MODULES(EMPATHY,
 198 [
 199    dbus-glib-1
 200    folks >= $FOLKS_REQUIRED
 201    folks-telepathy >= $FOLKS_REQUIRED
 202    glib-2.0 >= $GLIB_REQUIRED
 203    gio-2.0 >= $GLIB_REQUIRED
 204    gio-unix-2.0 >= $GLIB_REQUIRED
 205    libsecret-1 >= $LIBSECRET_REQUIRED
 206    gnutls >= $GNUTLS_REQUIRED
 207    gmodule-export-2.0
 208    gobject-2.0
 209    gsettings-desktop-schemas
 210    libxml-2.0
 211    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 212    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 213    x11
 214    gtk+-3.0 >= $GTK_REQUIRED
 215    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 216    libnotify >= $LIBNOTIFY_REQUIRED
 217    gcr-3 >= $GCR_REQUIRED
 218    libpulse
 219    libpulse-mainloop-glib
 220    webkitgtk-3.0 >= $WEBKIT_REQUIRED
 221    libsoup-2.4
 222    gee-0.8
 223 ])
 224
 225 # -----------------------------------------------------------
 226 # GStreamer
 227 # -----------------------------------------------------------
 228 AC_ARG_ENABLE(gst-1.0,
 229               AS_HELP_STRING([--enable-gst-1.0=@<:@no/yes/auto@:>@],
 230                              [build with GStreamer 1.0]),
 231                              enable_gst1=$enableval,
 232                              enable_gst1=auto)
 233
 234 # Try to use GStreamer 1.0 if available
 235 have_gst1="no"
 236 if test "x$enable_gst1" != "xno"; then
 237   PKG_CHECK_MODULES(EMPATHY_CALL,
 238   [
 239      farstream-0.2
 240      telepathy-farstream >= $TP_FS_REQUIRED
 241      clutter-1.0 >= $CLUTTER_REQUIRED
 242      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 243      clutter-gst-2.0
 244      gstreamer-1.0
 245      gstreamer-audio-1.0
 246      gstreamer-video-1.0
 247   ], have_gst1="yes", have_gst1="no")
 248
 249   if test "x$have_gst1" = "xyes"; then
 250     AC_DEFINE(HAVE_GST1, 1, [Build with GStreamer 1.0])
 251   fi
 252 fi
 253
 254 if test "x$enable_gst1" = "xyes" -a "x$have_gst1" != "xyes"; then
 255    AC_MSG_ERROR([Could not find GStreamer 1.0 dependencies:
 256
 257 $EMPATHY_CALL_PKG_ERRORS])
 258 fi
 259
 260 if test "x$have_gst1" != "xyes"; then
 261   PKG_CHECK_MODULES(EMPATHY_CALL,
 262   [
 263      farstream-0.1
 264      telepathy-farstream >= $TP_FS_REQUIRED
 265      clutter-1.0 >= $CLUTTER_REQUIRED
 266      clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 267      clutter-gst-1.0 >= 1.5.2
 268      gstreamer-0.10 >= $GSTREAMER_REQUIRED
 269      gstreamer-interfaces-0.10
 270   ])
 271 fi
 272
 273 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 274    [Name of provider for accounts imported from GOA])
 275
 276 AC_DEFINE(EMPATHY_UOA_PROVIDER,
 277     "im.telepathy.Account.Storage.UOA",
 278    [Name of provider for accounts imported from libaccounts])
 279
 280 # -----------------------------------------------------------
 281 # Enable debug
 282 # -----------------------------------------------------------
 283
 284 AC_ARG_ENABLE(debug,
 285   AS_HELP_STRING([--disable-debug],
 286                  [compile without debug code]),
 287     enable_debug=$enableval, enable_debug=yes )
 288
 289 if test x$enable_debug = xyes; then
 290   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 291 fi
 292
 293 # -----------------------------------------------------------
 294 # Language Support
 295 # -----------------------------------------------------------
 296 IT_PROG_INTLTOOL([0.50.0])
 297
 298 GETTEXT_PACKAGE=empathy
 299 AC_SUBST(GETTEXT_PACKAGE)
 300 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 301
 302 # -----------------------------------------------------------
 303 # gudev
 304 # -----------------------------------------------------------
 305 AC_ARG_ENABLE(gudev,
 306               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 307                              [build with gudev support]), ,
 308                              enable_gudev=auto)
 309
 310 if test "x$enable_gudev" != "xno"; then
 311
 312    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 313         have_gudev="yes", have_gudev="no")
 314
 315    if test "x$have_gudev" = "xyes"; then
 316       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 317    fi
 318 else
 319    have_gudev=no
 320 fi
 321
 322 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 323    AC_MSG_ERROR([Could not find gudev dependencies:
 324
 325 $UDEV_PKG_ERRORS])
 326 fi
 327 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 328
 329 # -----------------------------------------------------------
 330 # spellchecking checks: enchant and iso-codes
 331 # -----------------------------------------------------------
 332 AC_ARG_ENABLE(spell,
 333               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 334                              [Enable spell checking]), ,
 335                              enable_spell=auto)
 336
 337 if test "x$enable_spell" != "xno"; then
 338    PKG_CHECK_MODULES(ENCHANT,
 339    [
 340       enchant >= $ENCHANT_REQUIRED,
 341       iso-codes >= $ISO_CODES_REQUIRED
 342    ], have_enchant="yes", have_enchant="no")
 343
 344    if test "x$have_enchant" = "xyes"; then
 345       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 346       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 347          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 348             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 349             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 350             result=yes
 351       else
 352             result=no
 353             have_enchant="no"
 354       fi
 355       AC_MSG_RESULT([$result])
 356    fi
 357 else
 358    have_enchant=no
 359 fi
 360
 361 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 362    AC_MSG_ERROR([Could not find spell-checking dependencies:
 363
 364 $ENCHANT_PKG_ERRORS])
 365 fi
 366
 367 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 368
 369 # -----------------------------------------------------------
 370 # Map view checks: libchamplain
 371 # -----------------------------------------------------------
 372 AC_ARG_ENABLE(map,
 373               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 374                              [Enable map view]), ,
 375                              enable_map=auto)
 376
 377 if test "x$enable_map" != "xno"; then
 378
 379    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 380     [
 381        clutter-gtk-1.0
 382        champlain-gtk-0.12
 383        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 384     ], have_libchamplain="yes", have_libchamplain="no")
 385
 386    if test "x$have_libchamplain" = "xyes"; then
 387       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 388    fi
 389 else
 390    have_libchamplain=no
 391 fi
 392
 393 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 394    AC_MSG_ERROR([Could not find map view dependencies:
 395
 396 $LIBCHAMPLAIN_PKG_ERRORS])
 397 fi
 398
 399 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 400
 401 # -----------------------------------------------------------
 402 # location checks: geoclue
 403 # -----------------------------------------------------------
 404 AC_ARG_ENABLE(location,
 405               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 406                              [Enable location awareness]), ,
 407                              enable_location=auto)
 408
 409 if test "x$enable_location" != "xno"; then
 410    PKG_CHECK_MODULES(GEOCLUE,
 411    [
 412       geoclue >= $GEOCLUE_REQUIRED
 413    ], have_geoclue="yes", have_geoclue="no")
 414
 415    if test "x$have_geoclue" = "xyes"; then
 416       AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue])
 417    fi
 418 else
 419    have_geoclue="no"
 420 fi
 421
 422 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 423    AC_MSG_ERROR([Could not find location dependencies:
 424
 425 $GEOCLUE_PKG_ERRORS])
 426 fi
 427
 428 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 429 AC_SUBST(GEOCLUE_CFLAGS)
 430 AC_SUBST(GEOCLUE_LIBS)
 431
 432 # -----------------------------------------------------------
 433 # location checks: geocode-glib
 434 # -----------------------------------------------------------
 435 AC_ARG_ENABLE(geocode,
 436               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 437                              [Enable geocode support]), ,
 438                              enable_geocode=auto)
 439
 440 if test "x$enable_geocode" != "xno"; then
 441    PKG_CHECK_MODULES(GEOCODE,
 442    [
 443       geocode-glib >= $GEOCODE_GLIB_REQUIRED
 444    ], have_geocode="yes", have_geocode="no")
 445
 446    if test "x$have_geocode" = "xyes"; then
 447       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 448    fi
 449 else
 450    have_geocode="no"
 451 fi
 452
 453 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 454    AC_MSG_ERROR([Could not find geocode dependencies:
 455
 456 $GEOCODE_PKG_ERRORS])
 457 fi
 458
 459 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 460 AC_SUBST(GEOCODE_CFLAGS)
 461 AC_SUBST(GEOCODE_LIBS)
 462
 463 # -----------------------------------------------------------
 464 # nautilus-sendto
 465 # -----------------------------------------------------------
 466 AC_ARG_ENABLE(nautilus-sendto,
 467               AS_HELP_STRING([--enable-nautilus-sendto=@<:@no/yes/auto@:>@],
 468                              [build nautilus-sendto plugin]), ,
 469                              enable_nautilus_sendto=auto)
 470
 471 if test "x$enable_nautilus_sendto" != "xno"; then
 472    PKG_CHECK_MODULES(NST,
 473     [
 474        nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED
 475     ], have_nst="yes", have_nst="no")
 476 else
 477    have_nst=no
 478 fi
 479
 480 if test "x$enable_nautilus_sendto" = "xyes" -a "x$have_nst" != "xyes"; then
 481    AC_MSG_ERROR([Could not find nautilus-sendto dependencies:
 482
 483 $NST_PKG_ERRORS])
 484 fi
 485
 486 AM_CONDITIONAL(HAVE_NST, test "x$have_nst" = "xyes")
 487
 488 # -----------------------------------------------------------
 489 # goa-mc-plugin
 490 # -----------------------------------------------------------
 491 AC_ARG_ENABLE(goa,
 492               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 493                              [build GOA MC plugin]), ,
 494                              enable_goa=auto)
 495
 496 if test "x$enable_goa" != "xno"; then
 497    PKG_CHECK_MODULES(GOA,
 498     [
 499        mission-control-plugins
 500        goa-1.0 >= $GOA_REQUIRED
 501     ], have_goa="yes", have_goa="no")
 502 else
 503    have_goa=no
 504 fi
 505
 506 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 507    AC_MSG_ERROR([Could not find GOA dependencies:
 508
 509 $GOA_PKG_ERRORS])
 510 fi
 511
 512 if test "x$have_goa" = "xyes"; then
 513    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 514 fi
 515
 516 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 517
 518 # Optional dependency for avatar selection
 519 AC_ARG_WITH([cheese],
 520             AS_HELP_STRING([--with-cheese],
 521                            [enable cheese webcam support]),,
 522             with_cheese=auto)
 523
 524 if test x"$with_cheese" != x"no" ; then
 525    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 526    if test x${have_cheese} = xyes; then
 527      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 528    fi
 529    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 530      AC_MSG_ERROR([Cheese configured but not found:
 531
 532 $CHEESE_PKG_ERRORS])
 533    fi
 534 else
 535    have_cheese=no
 536 fi
 537 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 538
 539 # -----------------------------------------------------------
 540 # ubuntu-online-accounts support
 541 # -----------------------------------------------------------
 542 AC_ARG_ENABLE(ubuntu-online-accounts,
 543               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 544                              [build Ubuntu Online Accounts plugins]), ,
 545                              enable_ubuntu_online_accounts=auto)
 546
 547 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 548    PKG_CHECK_MODULES(UOA,
 549     [
 550        account-plugin
 551        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 552        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 553        libsignon-glib >= $LIBSIGNON_REQUIRED
 554     ], have_uoa="yes", have_uoa="no")
 555
 556    # provider plugin dir
 557    AC_MSG_CHECKING([Accounts provider plugin dir])
 558    ACCOUNTS_PROVIDER_PLUGIN_DIR=`pkg-config --variable=provider_plugindir account-plugin`
 559
 560    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 561    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 562
 563    # app plugin dir
 564    AC_MSG_CHECKING([Accounts provider app plugin dir])
 565    ACCOUNTS_APP_PLUGIN_DIR=`pkg-config --variable=application_plugindir account-plugin`
 566
 567    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 568    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 569
 570    # provider files dir
 571    AC_MSG_CHECKING([Accounts provider files dir])
 572    ACCOUNTS_PROVIDER_FILES_DIR=`pkg-config --variable=providerfilesdir libaccounts-glib`
 573
 574    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 575    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 576
 577    # service files dir
 578    AC_MSG_CHECKING([Accounts service files dir])
 579    ACCOUNTS_SERVICE_FILES_DIR=`pkg-config --variable=servicefilesdir libaccounts-glib`
 580
 581    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 582    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 583
 584    # application files dir
 585    AC_MSG_CHECKING([Accounts applications files dir])
 586    ACCOUNTS_APPLICATION_FILES_DIR=`pkg-config --variable=applicationfilesdir libaccounts-glib`
 587
 588    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 589    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 590
 591 else
 592    have_uoa=no
 593 fi
 594
 595 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 596    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 597
 598 $UOA_PKG_ERRORS])
 599 fi
 600
 601 if test "x$have_uoa" = "xyes"; then
 602    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 603 fi
 604
 605 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 606
 607 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 608    AC_MSG_CHECKING([Mission Control plugins dir])
 609    MISSION_CONTROL_PLUGINS_DIR=${libdir}/mission-control-plugins.`pkg-config --variable=MCP_ABI_VERSION mission-control-plugins`
 610
 611    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 612    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 613 fi
 614
 615
 616 # Help documentation
 617 YELP_HELP_INIT
 618
 619 # -----------------------------------------------------------
 620 # Coding style checks
 621 # -----------------------------------------------------------
 622 AC_ARG_ENABLE(coding-style-checks,
 623   AS_HELP_STRING([--disable-coding-style-checks],
 624                  [do not check coding style using grep]),
 625     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 626     [ENABLE_CODING_STYLE_CHECKS=yes])
 627
 628 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 629 # -----------------------------------------------------------
 630
 631 AC_CONFIG_FILES([
 632    Makefile
 633    data/Makefile
 634    data/empathy.desktop.in
 635    data/icons/Makefile
 636    data/themes/Makefile
 637    extensions/Makefile
 638    po/Makefile.in
 639    libempathy/Makefile
 640    libempathy-gtk/Makefile
 641    src/Makefile
 642    nautilus-sendto-plugin/Makefile
 643    goa-mc-plugin/Makefile
 644    ubuntu-online-accounts/Makefile
 645    ubuntu-online-accounts/mc-plugin/Makefile
 646    ubuntu-online-accounts/cc-plugins/Makefile
 647    ubuntu-online-accounts/cc-plugins/account-plugins/Makefile
 648    ubuntu-online-accounts/cc-plugins/providers/Makefile
 649    ubuntu-online-accounts/cc-plugins/services/Makefile
 650    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 651    help/Makefile
 652    tests/Makefile
 653    tests/interactive/Makefile
 654    tests/xml/Makefile
 655    tests/certificates/Makefile
 656    tools/Makefile
 657 ])
 658 AC_OUTPUT
 659
 660 echo "
 661 Configure summary:
 662
 663         Compiler....................:  ${CC}
 664         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 665         Linker Flags................:  ${LDFLAGS}
 666         Prefix......................:  ${prefix}
 667         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 668         Use GStreamer 1.0...........:  ${have_gst1}
 669
 670     Features:
 671         Spell checking (enchant)....:  ${have_enchant}
 672         Display maps (libchamplain).:  ${have_libchamplain}
 673         Location awareness (Geoclue):  ${have_geoclue}
 674         Geocode support (Geocode)...:  ${have_geocode}
 675         Cheese webcam support ......:  ${have_cheese}
 676         Camera monitoring...........:  ${have_gudev}
 677
 678     Extras:
 679         Nautilus-sendto plugin......:  ${have_nst}
 680         GOA MC plugin...............:  ${have_goa}
 681         Ubuntu Online plugins.......:  ${have_uoa}
 682 "